गतिशील एसक्यूएल लूप

समस्या यह है कि आप कर्सर के माध्यम से पुनरावृत्ति नहीं कर रहे हैं - कोई फ़ेच स्टेटमेंट या ऐसा कुछ नहीं है, इसलिए, मूल रूप से, आपके पास एक अनंत लूप है। इससे बचने के लिए आपको कुछ इस तरह करना होगा:

CREATE OR REPLACE PROCEDURE how_many_rows
   (p_in_table VARCHAR2) IS
   TYPE cur_cur IS REF CURSOR;
   v_cur_cur cur_cur;
   v_rowcount NUMBER(28);
   v_cur_txt VARCHAR2(299);
   v_row SOME_TABLE%ROWTYPE; --add row variable
BEGIN
   v_cur_txt := 'SELECT * FROM '|| p_in_table;

OPEN v_cur_cur FOR v_cur_txt;
   LOOP
      v_rowcount := v_cur_cur%ROWCOUNT;
      FETCH v_cur_cur INTO v_row; --fetch a row in it
         EXIT WHEN v_cur_cur%NOTFOUND;
   END LOOP;
CLOSE v_cur_cur;

DBMS_OUTPUT.PUT_LINE(v_rowcount);
END;

लेकिन, जैसा कि आप देख सकते हैं, ऐसा करने के लिए आपको यह जानना होगा कि आप किस तालिका को क्वेरी कर रहे हैं, इसलिए यह सामान्य समाधान नहीं है। हो सकता है कि इसके लिए कोई समाधान हो, लेकिन मेरा सुझाव है कि आप अधिक सरल और कुशल दृष्टिकोण का उपयोग करें, उदाहरण के लिए तत्काल तत्काल:

CREATE OR REPLACE PROCEDURE HOW_MANY_ROWS(p_in_table VARCHAR2)
       IS
v_tmp NUMBER;
BEGIN

EXECUTE IMMEDIATE 'SELECT COUNT(1) FROM ' || p_in_table INTO v_tmp;
DBMS_OUTPUT.PUT_LINE(v_tmp);

END;

ठीक है, मैंने आपके तरीके का उपयोग करके इसे प्राप्त करने के बारे में एक विचार दिया है, और यहां मैंने जो समाप्त किया है - बस अपनी तालिका से ROWNUM प्राप्त करें, प्रत्येक तालिका में यह है और आप जानते हैं कि यह प्रकार है - NUMBER। तो यह प्रक्रिया सामान्य स्थिति में काम करेगी:

CREATE OR REPLACE PROCEDURE how_many_rows
   (p_in_table VARCHAR2) IS
   TYPE cur_cur IS REF CURSOR;
   v_cur_cur cur_cur;
   v_rowcount NUMBER(28);
   v_cur_txt VARCHAR2(299);
   v_row NUMBER; --add rownum variable
BEGIN
   v_cur_txt := 'SELECT ROWNUM FROM '|| p_in_table; --select only rownum from target table

OPEN v_cur_cur FOR v_cur_txt;
   LOOP
      v_rowcount := v_cur_cur%ROWCOUNT;
      FETCH v_cur_cur INTO v_row; --fetch rownum in it
         EXIT WHEN v_cur_cur%NOTFOUND;
   END LOOP;
CLOSE v_cur_cur;

DBMS_OUTPUT.PUT_LINE(v_rowcount);
END;