ट्री व्यू इमेजकॉम्बो ड्रॉप-डाउन एक्सेस मेनू

परिचय।

ट्री व्यू कंट्रोल ट्यूटोरियल के इस सत्र में, हम इमेजकंबोबॉक्स कंट्रोल को प्रोग्राम करना सीखेंगे। हम ImageCombo कंट्रोल के साथ एक MS-Access प्रोजेक्ट ड्रॉप-डाउन मेनू बनाएंगे। ImageList से छवियों और उनके प्रमुख मूल्यों को प्रदर्शित करने के लिए एक दूसरा ImagecomboBox नियंत्रण है। नियंत्रण। इन दोनों ImageComboBox नियंत्रणों के लिए, छवियों की सूची एक सामान्य ImageList नियंत्रण से ली गई है। इस ट्यूटोरियल श्रृंखला के पहले के सत्र में, छवियों को कंप्यूटर से इमेजलिस्ट कंट्रोल में मैन्युअल रूप से अपलोड किया गया था।

ट्री व्यू कंट्रोल ट्यूटोरियल सत्र निम्नलिखित हैं जिन्हें हमने अब तक कवर किया है:

ट्री व्यू कंट्रोल ट्यूटोरियल सेशन लिंक।

1. माइक्रोसॉफ्ट ट्री व्यू कंट्रोल ट्यूटोरियल
2. ट्री व्यू कंट्रोल के साथ एक्सेस मेनू बनाना
3. ट्री व्यू कंट्रोल को इमेज असाइन करना
4. ट्री व्यू कंट्रोल-2 में इमेज असाइन करना
5. ट्री व्यू कंट्रोल चेक-मार्क ऐड डिलीट नोड्स

दोनों ImageComboBoxes के डेमो व्यू का विस्तार किया गया।

पूर्ण एमएस-एक्सेस प्रोजेक्ट ड्रॉप-डाउन मेनू छवि नीचे दी गई है:

ऊपर दिए गए फॉर्म का डिज़ाइन व्यू इमेज नीचे दिया गया है:

ड्रॉप-डाउन ImageComboBox स्रोत डेटा।

नया MS-Access प्रोजेक्ट ड्रॉप-डाउन मेनू का स्रोत डेटा हमारे पहले के एक्सेस मेनू प्रोजेक्ट से लिया गया है।

डेमो डेटाबेस अभी डाउनलोड करें, यदि आपने इसे पहले नहीं किया है, तो चौथे आइटम . से ऊपर दिया गया लिंक। यदि आप करते हैं, तो आपके पास वर्तमान सत्र को जारी रखने के लिए सभी आवश्यक डेटा ऑब्जेक्ट हैं।

तीन तालिकाएँ हैं:श्रेणियाँ, उत्पाद, और मेनू टेबल। श्रेणी और उत्पाद डेटा और रिपोर्ट के लिए डेटा फ़िल्टर पैरामीटर प्रपत्र प्रदर्शित करने के लिए दो रूप हैं।

हमारे पास दो और फ़ॉर्म हैं:frmMenu और frmMenu2 जिसका उपयोग हमने अपने पिछले ट्यूटोरियल सत्रों के लिए किया है।

श्रेणियों और उत्पाद डेटा आइटम का पूर्वावलोकन करने के लिए आपको दो रिपोर्टें मिलेंगी।

कुछ सरल संदेश प्रदर्शित करने के लिए दो मैक्रो। जटिल रिपोर्ट के लिए डेटा प्रोसेसिंग के लिए क्रिया-प्रश्नों को अनुक्रमित करने के लिए मैक्रोज़ का उपयोग किया जा सकता है। ये क्रियाएं पिछले ट्यूटोरियल सत्र में ट्री व्यू कंट्रोल प्रोजेक्ट मेनू से विकल्प चुनकर की गई हैं।

हमें इन सभी वस्तुओं की यहाँ भी आवश्यकता है क्योंकि हम ImageComboBox का उपयोग करके एक नया ड्रॉप-डाउन मेनू बनाएंगे। नियंत्रण। हमें नए ड्रॉप-डाउन नियंत्रण मेनू में विकल्पों का चयन करके इन सभी वस्तुओं को खोलने में सक्षम होना चाहिए, ठीक उसी तरह जैसे हमने frmMenu2 पर किया था। इसी डेटाबेस में ट्री व्यू कंट्रोल का उपयोग करके फॉर्म।

मेनू आपके संदर्भ के लिए तालिका चित्र नीचे दिया गया है।

ड्रॉप-डाउन मेनू फॉर्म के डिजाइन की तैयारी।

ऊपर दिए गए मेनू फॉर्म के डिज़ाइन व्यू की जाँच करें, वहाँ हमारे पास मेनू से संबंधित दो नियंत्रण हैं। एक इमेजलिस्ट कंट्रोल और एक इमेजकंबोबॉक्स कंट्रोल। छविसूची प्रदर्शित करने के लिए प्रपत्र के दाईं ओर एक और ImageComboBox नियंत्रण रखा गया है छवियां।

1. छविसूची की एक प्रति बनाएं frmMenu2 . से नियंत्रण करें फ़ॉर्म करें और इसे एक नए फ़ॉर्म पर चिपकाएँ, जैसे frmMenu3Combo .

   इस इमेजलिस्ट कंट्रोल में ऐसी छवियां हैं जिन्हें हमने अपने पिछले ट्यूटोरियल सत्र में कंप्यूटर से मैन्युअल रूप से अपलोड किया है। आप इसकी संपत्ति पत्रक खोल सकते हैं और छवियों और उनकी कुंजी . की जांच कर सकते हैं names. इमेजलिस्ट कंट्रोल पर राइट-क्लिक करें, ImageListCtl ऑब्जेक्ट को हाइलाइट करें और गुण विकल्प चुनें।

2. प्रपत्र पर बाईं ओर स्थित ImageComboBox नियंत्रण ड्रॉप-डाउन मेनू के लिए है, जिसका नाम है:imgCombo1 . Microsoft ImageComboBox Control ढूंढें ActiveX नियंत्रणों . से समूह बनाएं और इसे फॉर्म पर रखें। नियंत्रण का नाम बदलकर imgCombo1 . करें ।

3. imgCombo2 . नाम के साथ दाईं ओर एक और ImageComboBox नियंत्रण बनाएं . दूसरा ImageComboBox हम ImageList0 से छवियों और उनके प्रमुख नामों को प्रदर्शित करने के लिए उपयोग करेंगे ड्रॉप-डाउन सूची के रूप में नियंत्रण करें।

4. दूसरे ImageComboBox नियंत्रण के ऊपर एक लेबल नियंत्रण जोड़ें और इसके कैप्शन को छवि सूची में बदलें

इमेज-कॉम्बो-बॉक्स कंट्रोल में इमेज लिस्टिंग।

पहले, हम दूसरे imgCombo2 . के साथ काम करेंगे ImageList नियंत्रण से छवियों की सूची को नियंत्रित और प्रदर्शित करें। एक बार जब आप कोड से परिचित हो जाते हैं तो आप ड्रॉप-डाउन मेनू निर्माण प्रक्रिया को बहुत आसानी से समझ जाएंगे।

हमने frmMenu3Combo . को विभाजित किया है प्रपत्र मॉड्यूल VBA कोड दो भागों में। आइए हम पहला भाग लें और देखें कि इसमें हमारे पास क्या है।

संक्षेप में, वैश्विक घोषणा क्षेत्र में, मुख्य वस्तु चर घोषित किए गए हैं। फॉर्म_लोड () ईवेंट प्रक्रिया प्रपत्र पर ImageList नियंत्रण को उसके ऑब्जेक्ट वेरिएबल objimgList . पर प्रारंभ करती है और cboImageList() . को कॉल करता है ImageList नियंत्रण से छवियों को दूसरे ImageComboBox नियंत्रण में जोड़ने के लिए सबरूटीन। आइए कोड पर करीब से नज़र डालें।

Form_Load() . के साथ प्रथम-भाग vba कोड और cboImageList() नीचे सूचीबद्ध सबरूटीन्स:

Dim imgcombo1 As MSComctlLib.ImageCombo
Dim imgCombo2 As MSComctlLib.ImageCombo
Dim objimgList As MSComctlLib.ImageList
Const KeyPrfx As String = "X"

Private Sub Form_Load()

Set objimgList = Me.ImageList0.Object

cboImageList 'load imagelist-combo

'CreateMenu 'Create Drop-Down Menu
 
End Sub

Private Sub cboImageList()
Dim j As Integer
Dim strText As String

Set imgCombo2 = Me.ImageCombo2.Object
imgCombo2.ImageList = objimgList

For j = 1 To objimgList.ListImages.Count
    strText = objimgList.ListImages(j).Key
    imgCombo2.ComboItems.Add , , strText,j,,j
Next
    imgCombo2.ComboItems(1).Selected = True
End Sub

VBA कोड रिव्यू।

वैश्विक घोषणा क्षेत्र पर, हमने दो ImageComboBox नियंत्रण घोषित किए हैं, imgCombo1 प्रोजेक्ट मेनू और imgCombo2 . के लिए छविसूची . से छवियों को प्रदर्शित करने के लिए नियंत्रण। objimgList प्रपत्र पर ImageList नियंत्रण के लिए घोषित चर। कीप्रफएक्स X . वर्ण के साथ चर स्थिरांक के रूप में घोषित किया गया।

फॉर्म_लोड () . के भीतर घटना प्रक्रिया objimgList प्रपत्र पर ImageList नियंत्रण के साथ आरंभ किया गया है, कथन के साथ:सेट objimgList =Me.ImageList0.Object। अब, ImageList नियंत्रण में सभी प्री-लोडेड इमेज objimgList ऑब्जेक्ट के माध्यम से एक्सेस करने के लिए उपलब्ध हैं।

अगला स्टेटमेंट सब-रूटीन को कॉल करता है cboImageList() ImgCombo1 . में सभी छवियों को जोड़ने के लिए नियंत्रण।

क्रिएटमेनू () सबरूटीन कॉल पर फिलहाल टिप्पणी की गई है।

cboImageList() s . में ubroutine दो चर घोषित किए गए हैं।

इसके बाद, कथन सेट करें imgCombo2 =Me.ImageCombo2.Object ऑब्जेक्ट वेरिएबल imgCombo2 को फॉर्म पर दूसरा ImagecomboBox असाइन करता है।

ट्री व्यू की तरह imgCombo2 . को नियंत्रित करें एक छविसूची . है संपत्ति, ImageList के गुणों तक पहुँचने के लिए, ImageComboBox नियंत्रण के लिए ImageList नियंत्रण के संदर्भ को पारित करने के लिए। अगला कथन:imgCombo2.ImageList =objimgList ऐसा करता है।

अगला, के लिए . . . अगला ImageList नियंत्रण में छवियों की संख्या के लिए लूप चलता है।

पहले ImageList आइटम की कुंजी- मान ('form_close') strText . में सहेजा गया है चर। यहां, हमने इमेज लिस्ट कंट्रोल के मुख्य मूल्य को टेक्स्ट के रूप में या इमेजकॉम्बो इमेज के विवरण के रूप में लिया है, क्योंकि यह एकमात्र टेक्स्ट उपलब्ध है। टैग संपत्ति खाली है और जब हम ड्रॉप-डाउन मेनू के साथ काम करते हैं तो इस संपत्ति के साथ हमारे अन्य उपयोग होते हैं।

अगला कथन महत्वपूर्ण है जिसे हमें करीब से देखना है, जोड़ें ImageComboBox नियंत्रण की विधि। कथन का सिंटैक्स नीचे दिया गया है:

imgCombo2.ComboItems.Add [Index],[Key],[Text],[Image],[SelImage],[Indentation]

जोड़ें () . के सभी पैरामीटर विधि वैकल्पिक हैं। इस नियंत्रण के हमारे पहले परीक्षण के लिए, हम [पाठ], [छवि], के लिए मानों का उपयोग करेंगे और [इंडेंटेशन] केवल<मजबूत>. छवि सूची दृश्य के पहले परीक्षण के परिणाम को देखने के बाद, हम इस ImageCombo नियंत्रण पर [इंडेंटेशन] पैरामीटर मान का उपयोग नहीं करेंगे।

नोट:लेकिन, ध्यान रखें कि हमें इंडेंटेशन . की आवश्यकता होगी ड्रॉप-डाउन मेनू के लिए संपत्ति मूल्य मेनू आइटम को ट्री व्यू कंट्रोल पर रूट-नोड और चाइल्ड-नोड की तरह दिखने के लिए। हम [कुंजी] . का उपयोग करेंगे किसी विशिष्ट मेनू आइटम के टैग . तक पहुंचने के लिए पैरामीटर भी (कुंजी और टेक्स्ट पैरामीटर दोनों के लिए) संपत्ति मूल्य।

बढ़ती हुई छवि सूची इंडेंटेशन परम सेटिंग।

इंडेंटेशन के लिए वृद्धिशील मान लागू करने के बाद, ImageCombo2 में पहली टेस्ट रन छवि सूची नीचे दी गई छवि की तरह दिखेगी।:

उपरोक्त ट्रायल रन इमेज से इंडेंटेशन का प्रभाव स्पष्ट है। प्रत्येक आइटम को दाईं ओर ले जाया गया है, जो पिछले वाले से एक स्थान बड़ा है। रूट-लेवल और चाइल्ड नोड्स की तरह दिखने के लिए हम अपने प्रोजेक्ट मेनू आइटम नोड्स की स्थिति के लिए इस सुविधा का उपयोग कर सकते हैं।

strText . के बाद मान ('form_close') पहला चर j ImageList की अनुक्रमणिका संख्या को संदर्भित करता है, [SelImage] पैरामीटर जिसे हमने छोड़ दिया है और अगला मान j में है कॉम्बोबॉक्स सूची में रखे जाने पर प्रत्येक सूची आइटम के इंडेंटेशन के लिए उपयोग किया गया है। पहले परीक्षण चलाने के बाद और परिणाम देखने के बाद आप छवि अनुक्रमणिका मान के बाद सभी पैरामीटर हटा सकते हैं।

अगला कथन:imgCombo2.ComboItems(1).Selected =True ComboBox में पहला आइटम चुनता है। जब आप कोड के माध्यम से ImageCombo नियंत्रण से कोई आइटम चुनते हैं तो बदलें () ईवेंट सक्रिय होता है, लेकिन ऐसा तब नहीं होता जब आप सीधे प्रपत्र पर किसी आइटम का चयन करते हैं। अपडेट () ईवेंट मैन्युअल अपडेट करने वाले ईवेंट की उपेक्षा करता है, और कोड के माध्यम से आह्वान करने का प्रयास करता है।

फॉर्म को सेव करें frmMenu3Combo और इसे नॉर्मल व्यू में खोलें। दूसरे ImageList ComboBox नियंत्रण का विस्तार करें और परिणाम देखें। अल्पविराम और चर निकालें j अंत में, पहले वेरिएबल j के बाद, ImageList अनुक्रमणिका संख्या के लिए बनाए रखा जाता है।

प्रोजेक्ट ड्रॉप-डाउन मेनू का VBA कोड।

अब, हम एक्सेस ड्रॉप-डाउन मेनू बनाने का तरीका जानने के लिए फॉर्म मॉड्यूल वीबीए कोड के दूसरे भाग के साथ आगे बढ़ेंगे और कॉम्बोबॉक्स नियंत्रण आइटम का चयन करके एक्सेस फॉर्म, रिपोर्ट और मैक्रोज़ को कैसे खोलें।

VBA कोड के दूसरे भाग में CreateMenu() . शामिल है सबरूटीन और ImageCombo1_Click() e वेंट प्रक्रिया, नीचे सूचीबद्ध की गई है:

Private Sub CreateMenu()
Dim db As DAO.Database
Dim rst As DAO.Recordset
Dim strSQL As String
Dim strKey As String
Dim strText As String
Dim typ As Integer

Set imgcombo1 = Me.ImageCombo1.Object
imgcombo1.ImageList = objimgList

strSQL = "SELECT ID, Desc, PID, Type,Macro,Form,Report FROM Menu;"

Set db = CurrentDb
Set rst = db.OpenRecordset(strSQL, dbOpenDynaset)

Do While Not rst.EOF And Not rst.BOF
    If Len(Trim(Nz(rst!PID, ""))) = 0 Then
        strKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
        imgcombo1.ComboItems.Add , strKey, strText, 1, 2, 1 ' image index 1,2([image],[selectedimage])
        'imgcombo1.ComboItems.Add , strKey, strText, "folder_close", "folder_open", 1
    Else
        strKey = KeyPrfx & CStr(rst!ID)
        strText = rst!Desc
        imgcombo1.ComboItems.Add , strKey, strText, 4, 5, 4 'last param is spacing
        'imgcombo1.ComboItems.Add , strKey, strText, "left_arrow", "right_arrow", 4
     
        'Check for the presense of Type Code
        If Nz(rst!Type, 0) > 0 Then
                typ = rst!Type
                With imgcombo1.ComboItems
            Select Case typ
                'save type Code & Form/Report/Macro Name in Tag Property
                Case 1
                    .Item(strKey).Tag = typ & rst!Form
                Case 2
                    .Item(strKey).Tag = typ & rst!Report
                Case 3
                    .Item(strKey).Tag = typ & rst!Macro
            End Select
                End With
        End If
        
    End If
    rst.MoveNext
Loop
rst.Close
imgcombo1.ComboItems.Item(1).Selected = True
End Sub

Private Sub ImageCombo1_Click()
Dim strObject As String
Dim strTag As String
Dim typ As Integer

strTag = ImageCombo1.SelectedItem.Tag
typ = Val(strTag)
strObject = Mid(strTag, 2)

Select Case typ
    Case 1
        DoCmd.OpenForm strObject, acNormal
    Case 2
        DoCmd.OpenReport strObject, acViewPreview
    Case 3
        DoCmd.RunMacro strObject
End Select

End Sub

मुझे लगता है, वीबीए कोड से शुरू करने से पहले आपको टेबल इमेज (इस पृष्ठ के शीर्ष से तीसरी छवि) पर एक नज़र डालनी चाहिए, यदि आपने इसे एक्सेस प्रोजेक्ट मेनू निर्माण के पहले सत्र में नहीं किया है।

आईडी फ़ील्ड का एक विशिष्ट ID मान होता है और यह एक AutoNumber फ़ील्ड होता है।

दूसरा क्षेत्र विवरण ऑब्जेक्ट प्रकार समूह नाम (फ़ॉर्म, रिपोर्ट और मैक्रो) और फ़ॉर्म, रिपोर्ट और मैक्रो के वास्तविक ऑब्जेक्ट नाम हैं।

PID ऑब्जेक्ट समूह नामों के लिए (पैरेंट आईडी) फ़ील्ड मान खाली है:फ़ॉर्म, रिपोर्ट, और मैक्रोज़ . ये खाली PID मान आइटम हम ImageComboBox ड्रॉप-डाउन मेनू में बाईं स्थिति में रखेंगे, एक वर्ण स्थान इंडेंटेशन के साथ, और अन्य आइटम चार वर्ण स्थान के साथ आगे बढ़ेंगे। वस्तुओं की इन स्थिति के साथ, वे ट्री व्यू नियंत्रण में रूट-लेवल और चाइल्ड-लेवल नोड्स की तरह दिखेंगे, लेकिन हम कनेक्टिंग ट्री लाइन्स को याद करेंगे।

ImageComboBox चयनित आइटम नियंत्रण में छवि की जाँच करें, छवि सबसे बाईं ओर स्थित है। अगली पंक्ति में समूह आइटम बाईं ओर एक वर्ण स्थान के बाद स्थित है और अन्य समूह आइटम भी उसी स्थिति में दिखाई दे रहे हैं। प्रत्येक समूह के अंतर्गत चाइल्ड सदस्य आइटम चार वर्ण रिक्त स्थान के बाद स्थित हैं।

PID फ़ील्ड मान की जाँच की गई है और यदि खाली पाया जाता है तो हम मान लेते हैं कि यह एक समूह का नाम है अन्यथा यह एक एक्सेस ऑब्जेक्ट नाम है जिसे हमें खोलने की आवश्यकता है, जब उपयोगकर्ता उस पर क्लिक करता है, और उन्हें समूह के बाल सदस्यों के रूप में स्थान देता है। PID फ़ील्ड में वास्तविक कुंजी मान यहाँ महत्वपूर्ण नहीं है। किसी भी मामले में, हमें यहां इसकी आवश्यकता है। लेकिन, हम इसके बजाय इस उद्देश्य के लिए टाइप फ़ील्ड मान का उपयोग कर सकते हैं।

अगला, प्रकार फ़ील्ड में ऑब्जेक्ट प्रकार कोड होता है:1 – प्रपत्र का नाम , 2 - रिपोर्ट का नाम, और 3 - मैक्रो नाम . अगले तीन फ़ील्ड:फॉर्म, रिपोर्ट और मैक्रो में टाइप फ़ील्ड में उनके संबंधित कोड के आधार पर वास्तविक ऑब्जेक्ट नाम होते हैं। मैंने स्पष्टता के लिए तीन अलग-अलग क्षेत्रों का उपयोग किया है, उन सभी को एक कॉलम में भी रखा जा सकता है।

कोड टाइप करें और वस्तु का नाम जोड़ी (2rptश्रेणियां . कहें) ) ImageComboBox के टैग . में सहेजा जाएगा संपत्ति।

क्रिएटमेनू() सबरूटीन।

अब, CreateMenu() Subroutine के vba कोड पर।

डेटाबेस और अन्य चर शुरुआत में घोषित किए गए हैं।

imgcombo1 वस्तु v ariable को Me.ImageCombo1 के साथ इनिशियलाइज़ किया गया है। वस्तु फॉर्म पर।

इसके बाद, imgCombo1.ImageList प्रॉपर्टी को ImageList ऑब्जेक्ट objimgList Reference . के साथ लोड किया गया है , ताकि हम इमेजलिस्ट के इंडेक्स नंबर और की वैल्यू को सीधे एक्सेस कर सकें।

अगला, मेनू तालिका रिकॉर्ड सेट SQL स्ट्रिंग के साथ खुला है।

PID फ़ील्ड मान की जाँच कर ली गई है, यदि यह खाली है तो यह एक ऑब्जेक्ट समूह का नाम है, ID मान कांस्टेंट X से पहले लगाया जाता है और strKey . में सहेजा जाता है चर। फ़ील्ड विवरण मान strText . में सहेजा गया है चर।

अगला कथन ImageComboBox नियंत्रण की Add() विधि को कॉल करता है और पहला आइटम ड्रॉप-डाउन मेनू में जोड़ा गया है।

imgcombo1.ComboItems.Add , strKey, strText, 1, 2, 1

पहला पैरामीटर मान इंडेक्स नंबर छोड़ दिया गया है, लेकिन यह स्वचालित रूप से बनाया जाएगा। strKey वैरिएबल में आईडी फ़ील्ड मान 1 . होता है उपसर्ग स्थिरांक X . के साथ (X1 ) कुंजी . के रूप में पैरामीटर। strText विवरण . शामिल है क्षेत्र मूल्य। अगला मान 1 है छविसूची पहली छवि की (कुंजी-मान folder_close ) सूचकांक मूल्य। यदि आप उद्धरणों के भीतर 'folder_close' कुंजी-मान पसंद करते हैं तो आप ऐसा कर सकते हैं। अगला मान 2 दूसरी छवि ('folder_open') अनुक्रमणिका मान है या आप उद्धरणों और अंतिम पैरामीटर 1 में 'folder_open' का उपयोग कर सकते हैं इंडेंटेशन के लिए है।

नोट: छविसूची में छवियों के अनुक्रमणिका क्रम की पुष्टि करने के लिए ImageCombo2 . में इमेज लिस्टिंग ऑर्डर को नियंत्रित करें प्रदर्शन हमने पहले बनाया है। हम इंडेक्स वैल्यू को की वैल्यू के साथ एक स्पेस के साथ प्रीफिक्स कर सकते थे ताकि उस नंबर को की वैल्यू में भी जोड़ा जा सके ताकि यह [इमेज] 1 फॉर्म_क्लोज जैसा दिखे। [छवि] 2 फॉर्म_ओपन वगैरह। . . यह मैं आपके लिए एक अभ्यास के रूप में छोड़ दूंगा।

अगला, यदि PID फ़ील्ड मान शून्य नहीं है तो वास्तविक मेनू विकल्प जोड़ें होना चाहिए एड अन्य . के अंतर्गत खंड<मजबूत>. यहां, हमने पहले की तरह एक और ImageCombo आइटम जोड़ा है। [छवि] . के लिए और [SelImage] params हमने ImageList Item Index value 4 . लिया है और 5 . इंडेंटेशन परम मान 4 . है कैरेक्टर स्पेस।

ImageCombo आइटम के जोड़ें () . में विधि, अन्य . के अंतर्गत खंड, हमें एक्सेस ऑब्जेक्ट नाम (frmData entry) . को सहेजने की आवश्यकता है प्रकार . के साथ कोड 1 टैग . में (ImageCombo1.ComboItems.Item(strKey).Tag) संपत्ति। जब उपयोगकर्ता ड्रॉप-डाउन कॉम्बोबॉक्स मेनू से इस आइटम का चयन करता है, तो क्लिक () ईवेंट सक्रिय होता है, टैग संपत्ति का मूल्य निकाला गया है, टाइप कोड की जांच की गई है, यदि टाइप कोड 1 . है (फॉर्म) फिर टैग प्रॉपर्टी में फॉर्म-नाम (frmData entry) DoCmd.OpenForm . के साथ खुला है कमांड।

इस तरह सभी मेनू छवि कॉम्बोबॉक्स नियंत्रण में तालिका रिकॉर्ड जोड़ दिए गए हैं।

कथन imgcombo1.ComboItems.Item(1).Selected =True छवि कॉम्बोबॉक्स नियंत्रण में पहले आइटम को डिफ़ॉल्ट आइटम के रूप में चुनता है। इस कोड निष्पादन समय पर बदलें () ईवेंट सक्रिय होता है, लेकिन तब नहीं जब किसी आइटम को प्रपत्र दृश्य पर क्लिक करके चुना जाता है।

एनबी: ड्रॉप-डाउन मेनू ट्रायल रन के लिए फॉर्म खोलने से पहले, कृपया ‘क्रिएटमेनू से कमेंट सिंबल को हटा दें। Form_Load() . में कॉल लाइन घटना प्रक्रिया। ImageCombo2 Control में ImageList Control से इमेज डिस्प्ले के ट्रायल रन के दौरान, हमने अस्थायी रूप से इस लाइन पर टिप्पणी की है।

ImageCombo1_Click() जब उपयोगकर्ता छवि कॉम्बोबॉक्स नियंत्रण से कोई आइटम चुनता है तो ईवेंट सक्रिय हो जाता है। चयनित आइटम का टैग टाइप कोड और ऑब्जेक्ट नाम के लिए संपत्ति मूल्य की जाँच की गई है और इसे Docmd.Objecttype ObjectName के साथ खोलता है .

डेमो डेटाबेस ProjectMenuV221.accdb .zip प्रारूप में डाउनलोड करने के लिए नीचे दिया गया है।

शब्दकोश वस्तु

1. शब्दकोश मूल बातें
2. डिक्शनरी ऑब्जेक्ट बेसिक्स-2
3. शब्दकोश ऑब्जेक्ट की और आइटम को सॉर्ट करना
4. डिक्शनरी से रिकॉर्ड प्रदर्शित करें
5. कक्षा वस्तुओं को शब्दकोश आइटम के रूप में जोड़ें
6. क्लास ऑब्जेक्ट डिक्शनरी आइटम अपडेट करें