ओरेकल में प्रक्रिया और निष्पादित करने के लिए पैरामीटर के रूप में चयन विवरण पास करें

चूंकि आप उन स्तंभों को नहीं जानते हैं जो संकलन समय पर पास-इन क्वेरी द्वारा लौटाए जाएंगे, आप उन्हें लूप के अंदर स्थिर रूप से संदर्भित नहीं कर सकते।

आप dbms_sql का उपयोग कर सकते हैं गतिशील रूप से ऐसा करने के लिए पैकेज:

CREATE OR REPLACE PROCEDURE p_create_text_file (
   loc IN VARCHAR2
   , file IN VARCHAR2
   , select_statement in varchar2
   , line_statement in varchar2 -- not used?
)
IS
   fid UTL_FILE.FILE_TYPE := UTL_FILE.FOPEN (loc, file, 'W');

   -- for dbms_sql
   l_c pls_integer;
   l_col_cnt pls_integer;
   l_desc_t dbms_sql.desc_tab3;
   l_rc pls_integer;
   l_varchar varchar2(4000);
BEGIN
   -- create cursor and prepare from passed-in statement
   l_c := dbms_sql.open_cursor;
   dbms_sql.parse(c=>l_c, statement=>select_statement,
      language_flag=>dbms_sql.native);
   dbms_sql.describe_columns3(c => l_c, col_cnt => l_col_cnt,
      desc_t => l_desc_t);

   -- define all columns as strings; this will end up with implicit conversion
   -- of dates etc. using NLS settings, so shoudl be finsessed based on data
   -- actual data type really...
   for i in 1..l_col_cnt loop
      dbms_sql.define_column(c=>l_c, position=>i,
         column=>l_varchar, column_size=>4000);
   end loop;

   -- execute the query
   l_rc := dbms_sql.execute(c=>l_c);

   -- fetch each row in turn
   while dbms_sql.fetch_rows(c=>l_c) > 0 loop
      -- for each column from describe
      for i in 1..l_col_cnt loop
         -- get the column value for this row (again, as string...)
         dbms_sql.column_value(l_c, i, l_varchar);
         -- write out to file, with delimiter after first column
         if i > 1 then
            UTL_FILE.PUT (fid, ';');
         end if;
         UTL_FILE.PUT (fid, l_varchar);
      end loop;
      UTL_FILE.NEW_LINE (fid);
   end loop;

   dbms_sql.close_cursor(l_c);

   UTL_FILE.FCLOSE (fid);
EXCEPTION
    WHEN OTHERS THEN UTL_FILE.FCLOSE (fid);
END;
/

वह, मूल रूप से, पास-इन स्टेटमेंट को पार्स करता है, इसे निष्पादित करता है, प्रत्येक पंक्ति को प्राप्त करता है, प्रत्येक कॉलम मान को बदले में प्राप्त करता है (एक स्ट्रिंग के रूप में, जिसे निहित रूपांतरणों से बचने के लिए विस्तारित/विस्तारित किया जाना चाहिए), और उनमें से प्रत्येक को फ़ाइल में लिखता है बदले में - उनके बीच एक सीमांकक और प्रत्येक पंक्ति के बाद एक अंतिम नई-पंक्ति जोड़ना।

जब आपके अनाम ब्लॉक से कॉल किया जाता है जो एक फ़ाइल बनाता है:

NLS_CHARACTERSET;AL32UTF8
NLS_RDBMS_VERSION;11.2.0.4.0

सावधान रहें, थोगु, कि यह डीडीएल (जिसे पार्स किए जाने पर निष्पादित किया जाता है) सहित, दिए गए किसी भी संकेत को चलाएगा। यदि आप यह नियंत्रित नहीं करते हैं कि इसे कैसे कहा जाता है, और वास्तव में यदि आप करते भी हैं, तो आपको यह सत्यापित करने के लिए पास किए गए कथन का सत्यापन जोड़ना चाहिए कि यह वास्तव में केवल एक प्रश्न है।

आपको अन्य तरीकों का पता लगाना आसान हो सकता है, जैसे बाहरी टेबल (जैसा कि @ कौशिक ने सुझाव दिया था), या क्लाइंट कार्यक्षमता।

जैसा कि @kfinity ने एक टिप्पणी में सुझाव दिया है, आप क्वेरी को पार्स करने और निष्पादित करने के लिए एक रेफरी कर्सर का उपयोग कर सकते हैं, जिससे किसी भी चीज को चलाने से रोका जा सके। dbms_sql पैकेज रेफ कर्सर को देशी कर्सर में बदलने के लिए एक फ़ंक्शन है , इसलिए स्पष्ट खुले, पार्स और निष्पादित चरणों के उस इंसेटैड का उपयोग करना:

CREATE OR REPLACE PROCEDURE p_create_text_file (
   loc IN VARCHAR2
   , file IN VARCHAR2
   , select_statement in varchar2
   , line_statement in varchar2 -- not used?
)
IS
   fid UTL_FILE.FILE_TYPE := UTL_FILE.FOPEN (loc, file, 'W');

   -- for initial parse and execute
   l_refcursor sys_refcursor;

   -- for dbms_sql
   l_c pls_integer;
   l_col_cnt pls_integer;
   l_desc_t dbms_sql.desc_tab3;
   l_rc pls_integer;
   l_varchar varchar2(4000);
BEGIN
   -- open ref cursor for the statement
   open l_refcursor for select_statement;

   -- convert ref cursor to dbms_sql cursor
   l_c := dbms_sql.to_cursor_number(l_refcursor);
   dbms_sql.describe_columns3(c => l_c, col_cnt => l_col_cnt,
      desc_t => l_desc_t);

   -- define all columns as strings; this will end up with implicit conversion
   -- of dates etc. using NLS settings, so shoudl be finsessed based on data
   -- actual data type really...
   for i in 1..l_col_cnt loop
      dbms_sql.define_column(c=>l_c, position=>i,
         column=>l_varchar, column_size=>4000);
   end loop;

   -- fetch each row in turn
   while dbms_sql.fetch_rows(c=>l_c) > 0 loop
      -- for each column from describe
      for i in 1..l_col_cnt loop
         -- get the column value for this row (again, as string...)
         dbms_sql.column_value(l_c, i, l_varchar);
         -- write out to file, with delimiter after first column
         if i > 1 then
            UTL_FILE.PUT (fid, ';');
         end if;
         UTL_FILE.PUT (fid, l_varchar);
      end loop;
      UTL_FILE.NEW_LINE (fid);
   end loop;

   dbms_sql.close_cursor(l_c);

   UTL_FILE.FCLOSE (fid);
EXCEPTION
    WHEN OTHERS THEN UTL_FILE.FCLOSE (fid);
END;
/

... जो समान आउटपुट फाइल बनाता है।

संयोग से, यदि आप चाहें तो फ़ेच-रोज़ लूप से पहले कॉलम नामों को हेडर पंक्ति के रूप में भी लिख सकते हैं:

   -- write column names as header row
   for i in 1..l_col_cnt loop
      if i > 1 then
         UTL_FILE.PUT (fid, ';');
      end if;
      UTL_FILE.PUT (fid, l_desc_t(i).col_name);
   end loop;
   UTL_FILE.NEW_LINE (fid);