SQL सर्वर 2005 लेनदेन स्तर और संग्रहीत कार्यविधियाँ

कॉल किए जाने पर संग्रहीत प्रक्रिया प्रभावी रूप से लेनदेन अलगाव का उपयोग करेगी।

यदि संग्रहीत कार्यविधि स्वयं एक स्पष्ट अलगाव स्तर सेट करती है, तो संग्रहीत कार्यविधि के बाहर निकलने पर इसे रीसेट कर दिया जाएगा।

(संपादित करें:अभी-अभी चेक किया गया है और यह BOL के शब्दों के विपरीत है। "... यह उस कनेक्शन के लिए तब तक सेट रहता है जब तक कि इसे स्पष्ट रूप से नहीं बदला जाता" लेकिन नीचे से देखा जा सकता है)

CREATE PROC CheckTransLevel
AS
DECLARE @Result varchar(20)

SELECT @Result = CASE transaction_isolation_level 
                        WHEN 0 THEN 'Unspecified' 
                        WHEN 1 THEN 'ReadUncomitted' 
                        WHEN 2 THEN 'Readcomitted' 
                        WHEN 3 THEN 'Repeatable' 
                        WHEN 4 THEN 'Serializable' 
                        WHEN 5 THEN 'Snapshot' 
                  END 
FROM sys.dm_exec_sessions 
WHERE session_id = @@SPID

PRINT @Result

GO
CREATE PROC SetRCTransLevel
AS
PRINT 'Enter: SetRCTransLevel'
SET TRANSACTION ISOLATION LEVEL READ COMMITTED
EXEC CheckTransLevel
PRINT 'Exit: SetRCTransLevel'
GO

SET NOCOUNT ON

SET TRANSACTION ISOLATION LEVEL READ UNCOMMITTED

EXEC CheckTransLevel

EXEC SetRCTransLevel

EXEC CheckTransLevel

परिणाम

ReadUncomitted
Enter: SetRCTransLevel
Readcomitted
Exit: SetRCTransLevel
ReadUncomitted