यह थोड़ा मुश्किल है, लेकिन यह निश्चित रूप से संभव है।
आइए एक बिंदु से दूसरे बिंदु तक असर की गणना करके शुरू करें। एक प्रारंभिक बिंदु, एक असर और एक दूरी को देखते हुए, निम्न फ़ंक्शन गंतव्य बिंदु लौटाएगा:
CREATE FUNCTION [dbo].[func_MoveTowardsPoint](@start_point geography,
@end_point geography,
@distance int) /* Meters */
RETURNS geography
AS
BEGIN
DECLARE @ang_dist float = @distance / 6371000.0; /* Earth's radius */
DECLARE @bearing decimal(18,15);
DECLARE @lat_1 decimal(18,15) = Radians(@start_point.Lat);
DECLARE @lon_1 decimal(18,15) = Radians(@start_point.Long);
DECLARE @lat_2 decimal(18,15) = Radians(@end_point.Lat);
DECLARE @lon_diff decimal(18,15) = Radians(@end_point.Long - @start_point.Long);
DECLARE @new_lat decimal(18,15);
DECLARE @new_lon decimal(18,15);
DECLARE @result geography;
/* First calculate the bearing */
SET @bearing = ATN2(sin(@lon_diff) * cos(@lat_2),
(cos(@lat_1) * sin(@lat_2)) -
(sin(@lat_1) * cos(@lat_2) *
cos(@lon_diff)));
/* Then use the bearing and the start point to find the destination */
SET @new_lat = asin(sin(@lat_1) * cos(@ang_dist) +
cos(@lat_1) * sin(@ang_dist) * cos(@bearing));
SET @new_lon = @lon_1 + atn2( sin(@bearing) * sin(@ang_dist) * cos(@lat_1),
cos(@ang_dist) - sin(@lat_1) * sin(@lat_2));
/* Convert from Radians to Decimal */
SET @new_lat = Degrees(@new_lat);
SET @new_lon = Degrees(@new_lon);
/* Return the geography result */
SET @result =
geography::STPointFromText('POINT(' + CONVERT(varchar(64), @new_lon) + ' ' +
CONVERT(varchar(64), @new_lat) + ')',
4326);
RETURN @result;
END
मैं समझता हूं कि आपको एक ऐसे फ़ंक्शन की आवश्यकता है जो एक लिनेस्ट्रिंग को इनपुट के रूप में लेता है, न कि केवल प्रारंभ और समाप्ति बिंदु। बिंदु को समेकित रेखा खंडों के पथ के साथ आगे बढ़ना है, और पथ के "कोनों" के चारों ओर घूमना जारी रखना चाहिए। यह पहली बार में जटिल लग सकता है, लेकिन मुझे लगता है कि इसे इस प्रकार निपटाया जा सकता है:
- अपनी लाइनस्ट्रिंग के प्रत्येक बिंदु के माध्यम से
STPointN() के साथ पुनरावृति करें, x=1 से x=STNumPoints()। STDistance()से दूरी का पता लगाएं पुनरावृत्ति में वर्तमान बिंदु के बीच अगले बिंदु तक:@linestring.STPointN(x).STDistance(@linestring.STPointN(x+1))-
यदि उपरोक्त दूरी> आपकी इनपुट दूरी 'n':
...तो गंतव्य बिंदु इस बिंदु और अगले के बीच है। बस
func_MoveTowardsPointलागू करें बिंदु x को प्रारंभ बिंदु के रूप में, बिंदु x+1 को अंतिम बिंदु के रूप में, और दूरी n के रूप में। परिणाम लौटाएं और पुनरावृत्ति को तोड़ें।अन्य:
... गंतव्य बिंदु पुनरावृति में अगले बिंदु से पथ में आगे है। बिंदु x और बिंदु x+1 के बीच की दूरी को अपनी दूरी 'n' से घटाएं। संशोधित दूरी के साथ पुनरावृत्ति जारी रखें।
आपने देखा होगा कि हम उपरोक्त के बजाय पुनरावर्ती रूप से आसानी से पुनरावर्ती रूप से कार्यान्वित कर सकते हैं।
आइए इसे करते हैं:
CREATE FUNCTION [dbo].[func_MoveAlongPath](@path geography,
@distance int,
@index int = 1)
RETURNS geography
AS
BEGIN
DECLARE @result geography = null;
DECLARE @num_points int = @path.STNumPoints();
DECLARE @dist_to_next float;
IF @index < @num_points
BEGIN
/* There is still at least one point further from the point @index
in the linestring. Find the distance to the next point. */
SET @dist_to_next = @path.STPointN(@index).STDistance(@path.STPointN(@index + 1));
IF @distance <= @dist_to_next
BEGIN
/* @dist_to_next is within this point and the next. Return
the destination point with func_MoveTowardsPoint(). */
SET @result = [dbo].[func_MoveTowardsPoint](@path.STPointN(@index),
@path.STPointN(@index + 1),
@distance);
END
ELSE
BEGIN
/* The destination is further from the next point. Subtract
@dist_to_next from @distance and continue recursively. */
SET @result = [dbo].[func_MoveAlongPath](@path,
@distance - @dist_to_next,
@index + 1);
END
END
ELSE
BEGIN
/* There is no further point. Our distance exceeds the length
of the linestring. Return the last point of the linestring.
You may prefer to return NULL instead. */
SET @result = @path.STPointN(@index);
END
RETURN @result;
END
इसके साथ, कुछ परीक्षण करने का समय आ गया है। आइए मूल लिनेस्ट्रिंग का उपयोग करें जो प्रश्न में प्रदान किया गया था, और हम गंतव्य बिंदुओं का अनुरोध 350m पर, 3500m पर और 7000m पर करेंगे:
DECLARE @g geography;
SET @g = geography::STGeomFromText('LINESTRING(-122.360 47.656,
-122.343 47.656,
-122.310 47.690)', 4326);
SELECT [dbo].[func_MoveAlongPath](@g, 350, DEFAULT).ToString();
SELECT [dbo].[func_MoveAlongPath](@g, 3500, DEFAULT).ToString();
SELECT [dbo].[func_MoveAlongPath](@g, 7000, DEFAULT).ToString();
हमारा परीक्षण निम्नलिखित परिणाम देता है:
POINT (-122.3553270591861 47.6560002502638)
POINT (-122.32676470116748 47.672728464582583)
POINT (-122.31 47.69)
ध्यान दें कि हमारे द्वारा अनुरोधित अंतिम दूरी (7000m) लिनेस्ट्रिंग की लंबाई से अधिक थी, इसलिए हमें अंतिम बिंदु लौटा दिया गया। इस मामले में, यदि आप चाहें, तो आप आसानी से NULL को वापस करने के लिए फ़ंक्शन को संशोधित कर सकते हैं।
