Oracle:IN खंड के साथ पैरामीटरयुक्त क्वेरी शून्य मान लौटाती है

आप अल्पविराम से अलग की गई सूची को एक पैरामीटर (बाइंड वैरिएबल) के रूप में पास कर सकते हैं, लेकिन आप इसे एक सबक्वेरी में पार्स करने के लिए जिम्मेदार हैं। इस थ्रेड पर आधारित समाधान regexp_substr का उपयोग करता है।

CREATE or REPLACE PROCEDURE p_getdata(A IN VARCHaR2, cur OUT sys_refcursor)
AS
BEGIN
open cur for  'with t1 as (select :A col from dual),
     t2 as (select level lvl,to_number(regexp_substr(col,''[^,]+'', 1, level)) col 
              from t1 connect by regexp_substr(col, ''[^,]+'', 1, level) is not null)
select col as id from t2' using A;
END;
/

प्रक्रिया को सरल बनाया गया है, लेकिन इसका उपयोग करने की भावना प्रदान करनी चाहिए।

डायनेमिक SQL (स्ट्रिंग्स का संयोजन) के उपयोग के विरुद्ध बड़ा लाभ यह है कि आपको प्रत्येक निष्पादन पर कथन को पार्स करने की आवश्यकता नहीं है। सुरक्षा का जिक्र नहीं है (एसक्यूएल इंजेक्शन का डर)।

उपयोग:

DECLARE 
  l_cur SYS_REFCURSOR;
  l_id NUMBER;
BEGIN 
  p_getdata('1,1000,282828,4',l_cur);
 LOOP
    FETCH l_cur INTO l_id ;
    EXIT WHEN l_cur%NOTFOUND;
    dbms_output.put_line(l_id);
 END LOOP;
END;
/


1
1000
282828
4

अपडेट करें

उपरोक्त प्रक्रिया को सरल बनाया गया है, अपनी कार्यक्षमता प्राप्त करने के लिए आपको कर्सर में इस तरह की एक क्वेरी का उपयोग करना चाहिए (यानी अपनी क्वेरी में परिणाम लागू करने के बजाय सबक्वायरी फैक्टरिंग का उपयोग करके सभी तीन पैरामीटर को अलग-अलग सबक्वायरी में विभाजित करें)

CREATE or REPLACE PROCEDURE p_getdata(A IN VARCHAR2, B in VARCHAR2, c in VARCHAR2, cur OUT sys_refcursor)
AS
BEGIN
open cur for  'with ta1 as (select :A col from dual),
     ta2 as (select level lvl,to_number(regexp_substr(col,''[^,]+'', 1, level)) col 
              from ta1 connect by regexp_substr(col, ''[^,]+'', 1, level) is not null),
 tb1 as (select :B col from dual),
     tb2 as (select level lvl,to_number(regexp_substr(col,''[^,]+'', 1, level)) col 
              from tb1 connect by regexp_substr(col, ''[^,]+'', 1, level) is not null),
 tc1 as (select :C col from dual),
     tc2 as (select level lvl,to_number(regexp_substr(col,''[^,]+'', 1, level)) col 
              from tc1 connect by regexp_substr(col, ''[^,]+'', 1, level) is not null)              
select firstname, lastname, streetname, city
from mytable 
where zip IN (select col from ta2) AND 
      streetnumber IN (select col from tb2) AND 
      apt_num in (select col from tc2)' using A, B, C;
END;
/

परीक्षा उत्तीर्ण

DECLARE 
  l_cur SYS_REFCURSOR;
  l_firstname VARCHAR2(20);
  l_lastname VARCHAR2(20);
  l_streetname VARCHAR2(20);
  l_city VARCHAR2(20);
BEGIN 
  p_getdata('1100,,1200','1,2','11,12' ,l_cur);
 LOOP
    FETCH l_cur INTO l_firstname, l_lastname, l_streetname, l_city;
    EXIT WHEN l_cur%NOTFOUND;
    dbms_output.put_line(l_firstname|| ' ' || l_lastname || ' ' || l_streetname  || ' ' || l_city);
 END LOOP;
END;
/