ऊपर दिए गए @foxidrive की मदद से मैं फ़ोल्डरों की तारीख प्राप्त करने में कामयाब रहा, जैसा कि मैं चाहता था कि वे YYYY-MM-DD HH-MIN-SEC हों।
इन फ़ोल्डरों में gzipped .sql डेटाबेस संग्रहीत हैं, जो adityasatrio की MySQL बैकअप बैच स्क्रिप्ट के कारण संग्रहीत हैं। ।
इस जवाब से @Magoo की मदद से https://stackoverflow.com/a/17521693/1010918 मैं रखते समय all सभी फ़ोल्डर्स (nameDir) को हटाने में कामयाब रहा नवीनतम N फ़ोल्डर (nameDir) और नहीं किसी भी फाइल को छूना जो निर्देशिका में हो सकती है (बैकअपडिर)।
यहां पूरी कार्यशील स्क्रिप्ट है।
pause . की किसी भी घटना को बेझिझक निकालें और और echo करने के लिए नहीं देखें कि कमांड प्रॉम्प्ट के अंदर क्या चल रहा है।
इसके अतिरिक्त इसे विंडोज टास्क शेड्यूलर में जोड़ें और आपके पास स्थानीय विकास वातावरण के लिए एक ठोस बैकअप समाधान है जो MySQL डेटाबेस का उपयोग करता है।
कृपया उन लोगों को धन्यवाद दें जिन्होंने मुझे इसे पूरा करने में मदद की। आप लोगों के बिना मुझे केवल MySQL डेटाबेस को स्थानीय रूप से सहेजने के लिए एक महंगे विंडोज ऐप का उपयोग करना पड़ता।
(..और हमारी अगली ट्रिक के लिए हम .sql फाइलों का बैकअप लेते समय त्रुटि होने पर खुद को एक त्रुटि लॉग ईमेल करने जा रहे हैं.. लेकिन यह एक और दिन के लिए एक और सवाल और कहानी है ..)
@echo off
set dbUser=root
set dbPassword=root
set "backupDir=D:\MySQLDumps"
set "mysqldump=C:\wamp\bin\mysql\mysql5.6.17\bin\mysqldump.exe"
set "mysqlDataDir=C:\wamp\bin\mysql\mysql5.6.17\data"
set "zip=C:\Program Files\7-Zip\7z.exe"
:: https://stackoverflow.com/a/31789045/1010918 foxidrive's answer helped me get the folder with the date and time I wanted
rem The four lines below will give you reliable YY DD MM YYYY HH Min Sec MS variables in XP Pro and higher.
for /f "tokens=2 delims==" %%a in ('wmic OS Get localdatetime /value') do set "dt=%%a"
set "YY=%dt:~2,2%" & set "YYYY=%dt:~0,4%" & set "MM=%dt:~4,2%" & set "DD=%dt:~6,2%"
set "HH=%dt:~8,2%" & set "Min=%dt:~10,2%" & set "Sec=%dt:~12,2%" & set "MS=%dt:~15,3%"
set "dirname=%YYYY%-%MM%-%DD% %HH%-%Min%-%Sec%"
:: remove echo here if you like
echo "dirName"="%dirName%"
:: switch to the "data" folder
pushd "%mysqlDataDir%"
:: create backup folder if it doesn't exist
if not exist "%backupDir%\%dirName%\" mkdir "%backupDir%\%dirName%"
:: iterate over the folder structure in the "data" folder to get the databases
for /d %%f in (*) do (
:: remove echo here if you like
echo processing folder "%%f"
"%mysqldump%" --host="localhost" --user=%dbUser% --password=%dbPassword% --single-transaction --add-drop-table --databases %%f > "%backupDir%\%dirName%\%%~nxf.sql"
"%zip%" a -tgzip "%backupDir%\%dirName%\%%~nxf.sql.gz" "%backupDir%\%dirName%\%%~nxf.sql"
del "%backupDir%\%dirName%\%%~nxf.sql"
)
popd
:: delete all folders but the latest 2
:: https://stackoverflow.com/a/17521693/1010918 Magoo's answer helped me get what I wanted to do with the folders
:: for /f "skip=2 delims=" %G in ('dir /B /ad-h /o-d') DO echo going to delete %G
:: below following my version with rd (remove dir) command and /s and /q
:: remove echo before rd to really delete the folders in question!!
:: attention they will be deleted with content in them!!
:: change the value after skip= to what you like, this is the amount of latest folders to keep in your backup directory
for /f "skip=2 delims=" %%a in (' dir "%backupDir%\" /b /ad-h /o-d') do echo rd /s /q "%backupDir%\%%a"
:: remove pause here if you like and add the file to Windows Task Manager
pause
