ओरेकल:क्या मैं प्रोग्रामेटिक रूप से बता सकता हूं कि किसी प्रक्रिया में कोई प्रतिबद्धता है या नहीं?

मेरे पास इसके लिए लिखी गई एक पैकेज प्रक्रिया है। मैं नीचे कोड पेस्ट करूंगा।

इसका उपयोग करने के लिए, बस "start_no_commit_section" को आपके द्वारा दिए गए नाम से कॉल करें। फिर, बाद में, इसी नाम से "end_no_commit_section" को कॉल करें। यदि कोई कमिट (या रोलबैक) जारी किया गया है, तो "end_no_commit_section" पर कॉल करने से त्रुटि उत्पन्न होगी।

दुर्भाग्य से, यह आपको यह नहीं बताता कि कहां प्रतिबद्ध हुआ। अगर मेरे पास देखने के लिए बहुत सारे कोड हैं, तो मैं आम तौर पर अपने कोड पर DBMS_HPROF चलाऊंगा और फिर HPROF परिणामों में एक कमिट की तलाश करूंगा (जो मुझे सटीक लाइन नंबर बताएगा)।

  CREATE OR REPLACE PACKAGE BODY XXCUST_TRANSACTION_UTIL AS
  ----------------------------------------------------------------
  -- See package spec for comments
  ----------------------------------------------------------------
  TYPE no_commit_section_t IS RECORD (local_transaction_id VARCHAR2 (200));

  TYPE no_commit_sections_tab IS TABLE OF no_commit_section_t
                                   INDEX BY VARCHAR2 (80);

  g_no_commit_sections   no_commit_sections_tab;

  PROCEDURE start_no_commit_section (p_section_name VARCHAR2) IS
    l_section   no_commit_section_t;
  BEGIN
    l_section.local_transaction_id                          := DBMS_TRANSACTION.local_transaction_id (create_transaction => TRUE);
    g_no_commit_sections (SUBSTR (p_section_name, 1, 80))   := l_section;
  END start_no_commit_section;


  PROCEDURE end_no_commit_section (p_section_name VARCHAR2) IS
    l_local_transaction_id   VARCHAR2 (200);
  BEGIN
    l_local_transaction_id   := DBMS_TRANSACTION.local_transaction_id (create_transaction => TRUE);

    IF l_local_transaction_id != g_no_commit_sections (SUBSTR (p_section_name, 1, 80)).local_transaction_id THEN
      -- There has been a commit or a rollback in the no-commit section
      raise_application_error(-20001,'A commit or rollback has been detected in "No commit" section ' || p_section_name || '.');
    END IF;
  EXCEPTION
    WHEN no_data_found THEN
      -- Caller specified a non-existent commit section
      raise_application_error(-20001,'"No commit" section ' || p_section_name || ' not established.');
  END end_no_commit_section;
END XXCUST_TRANSACTION_UTIL;