Oracle डेटा मास्किंग

यह समस्या 12c में STANDARD_HASH फंक्शन से आसानी से हल हो जाती है। ।

पिछले संस्करणों में समाधान केवल थोड़ा अधिक जटिल है। DBMS_CRYPTO के चारों ओर एक साधारण आवरण बनाएं जो STANDARD_HASH की तरह कार्य करता है:

--Imitation of the 12c function with the same name.
--Remember to drop this function when you upgrade!
create or replace function standard_hash(
    p_string varchar2,
    p_method varchar2 default 'SHA1'
) return varchar2 is
    v_method number;
    v_invalid_identifier exception;
    pragma exception_init(v_invalid_identifier, -904);
begin
    --Intentionally case-sensitive, just like the 12c version.
    if p_method = 'SHA1' then
        v_method := dbms_crypto.hash_sh1;
    --These algorithms are only available in 12c and above.
    $IF NOT DBMS_DB_VERSION.VER_LE_11 $THEN
        elsif p_method = 'SHA256' then
            v_method := dbms_crypto.hash_sh256;
        elsif p_method = 'SHA384' then
            v_method := dbms_crypto.hash_sh384;
        elsif p_method = 'SHA512' then
            v_method := dbms_crypto.hash_sh512;
    $END
    elsif p_method = 'MD5' then
        v_method := dbms_crypto.hash_md5;
    else
        raise v_invalid_identifier;
    end if;

    return rawToHex(dbms_crypto.hash(utl_raw.cast_to_raw(p_string), v_method));
end;
/

फ़ंक्शन को काम करने के लिए आपको SYS के साथ लॉगऑन करने और अपने उपयोगकर्ता को DBMS_CRYPTO तक पहुंच प्रदान करने की आवश्यकता हो सकती है:

grant execute on sys.dbms_crypto to <your_schema>;

एक सार्वजनिक पर्यायवाची बनाएं, इसे सभी को दें, और यह ठीक उसी तरह काम करता है।

create public synonym standard_hash for <schema with function>.standard_hash;
grant execute on standard_hash to public;

select standard_hash('Some text', 'MD5') from dual;
    9DB5682A4D778CA2CB79580BDB67083F

select standard_hash('Some text', 'md5') from dual;
    ORA-00904: : invalid identifier

फ़ंक्शन का उपयोग करने का एक सरल उदाहरण यहां दिया गया है:

update some_table
set column1 = standard_hash(column1),
    column2 = standard_hash(column2);

लेकिन बड़ी मात्रा में डेटा अपडेट करना धीमा हो सकता है। नई तालिका बनाने, पुराने को छोड़ने, नए का नाम बदलने आदि के लिए तेज़ हो सकता है। और हैश मान कॉलम आकार से बड़ा हो सकता है, alter table some_table modify column1 varchar2(40 byte);

यह मुझे चकित करता है कि इतना आसान काम करने के लिए कितने उत्पाद और उपकरण हैं।