क्या आप अपने लक्ष्य को प्राप्त करने के लिए PIPELINED फ़ंक्शन का उपयोग करने पर विचार करेंगे?
मैंने इस तरह के एक समारोह का एक उदाहरण लिखा है। उदाहरण तालिका, नमूना डेटा और PIVOT . पर आधारित है टॉम कायटे के लेखों की क्वेरी जो आप उनकी साइट पर पा सकते हैं:
PIVOT/UNPIVOT के बारे में Tom Kyte का लेख
PIPELINED कार्यों के बारे में टॉम कायटे का लेख
उदाहरण इस प्रकार काम करता है।
हम दो प्रकार बनाते हैं:
- t_pivot_test_obj - वह प्रकार जिसमें स्तंभ होते हैं जिन्हें हम XML से पुनर्प्राप्त करना चाहते हैं
- t_pivot_test_obj_tab - उपरोक्त वस्तुओं की नेस्टेड तालिका प्रकार।
फिर हम एक PIPELINED फ़ंक्शन बनाते हैं जिसमें PIVOT . के साथ क्वेरी होती है , जो एक्सएमएल उत्पन्न करता है (इसलिए आपको उन मानों को हार्ड-कोड करने की ज़रूरत नहीं है जिन्हें आप पिवट करना चाहते हैं)। यह फ़ंक्शन जेनरेट किए गए एक्सएमएल से डेटा निकालता है और कॉलिंग क्वेरी में (पीआईपीई) पंक्तियों को पास करता है क्योंकि वे उत्पन्न होते हैं (फ्लाई पर - वे एक बार में उत्पन्न नहीं होते हैं जो प्रदर्शन के लिए महत्वपूर्ण है)।
अंत में, आप एक क्वेरी लिखते हैं जो उस फ़ंक्शन से रिकॉर्ड का चयन करती है (अंत में ऐसी क्वेरी का एक उदाहरण है)।
CREATE TABLE pivot_test (
id NUMBER,
customer_id NUMBER,
product_code VARCHAR2(5),
quantity NUMBER
);
INSERT INTO pivot_test VALUES (1, 1, 'A', 10);
INSERT INTO pivot_test VALUES (2, 1, 'B', 20);
INSERT INTO pivot_test VALUES (3, 1, 'C', 30);
INSERT INTO pivot_test VALUES (4, 2, 'A', 40);
INSERT INTO pivot_test VALUES (5, 2, 'C', 50);
INSERT INTO pivot_test VALUES (6, 3, 'A', 60);
INSERT INTO pivot_test VALUES (7, 3, 'B', 70);
INSERT INTO pivot_test VALUES (8, 3, 'C', 80);
INSERT INTO pivot_test VALUES (9, 3, 'D', 90);
INSERT INTO pivot_test VALUES (10, 4, 'A', 100);
COMMIT;
CREATE TYPE t_pivot_test_obj AS OBJECT (
customer_id NUMBER,
product_code VARCHAR2(5),
sum_quantity NUMBER
);
/
CREATE TYPE t_pivot_test_obj_tab IS TABLE OF t_pivot_test_obj;
/
CREATE OR REPLACE FUNCTION extract_from_xml RETURN t_pivot_test_obj_tab PIPELINED
AS
v_xml XMLTYPE;
v_item_xml XMLTYPE;
v_index NUMBER;
v_sum_quantity NUMBER;
CURSOR c_customer_items IS
SELECT customer_id, product_code_xml
FROM (SELECT customer_id, product_code, quantity
FROM pivot_test)
PIVOT XML (SUM(quantity) AS sum_quantity FOR (product_code) IN (SELECT DISTINCT product_code
FROM pivot_test));
BEGIN
-- loop through all records returned by query with PIVOT
FOR v_rec IN c_customer_items
LOOP
v_xml := v_rec.product_code_xml;
v_index := 1;
-- loop through all ITEM elements for each customer
LOOP
v_item_xml := v_xml.EXTRACT('/PivotSet/item[' || v_index || ']');
EXIT WHEN v_item_xml IS NULL;
v_index := v_index + 1;
IF v_item_xml.EXTRACT('/item/column[@name="SUM_QUANTITY"]/text()') IS NOT NULL THEN
v_sum_quantity := v_item_xml.EXTRACT('/item/column[@name="SUM_QUANTITY"]/text()').getNumberVal();
ELSE
v_sum_quantity := 0;
END IF;
-- finally, for each customer and item - PIPE the row to the calling query
PIPE ROW(t_pivot_test_obj(v_rec.customer_id,
v_item_xml.EXTRACT('/item/column[@name="PRODUCT_CODE"]/text()').getStringVal(),
v_sum_quantity));
END LOOP;
END LOOP;
END;
/
SELECT customer_id, product_code, sum_quantity
FROM TABLE(extract_from_xml())
;
आउटपुट:
CUSTOMER_ID PRODUCT_CODE SUM_QUANTITY
---------------------- ------------ ----------------------
1 A 10
1 B 20
1 C 30
1 D 0
2 A 40
2 B 0
2 C 50
2 D 0
3 A 60
3 B 70
3 C 80
3 D 90
4 A 100
4 B 0
4 C 0
4 D 0
16 rows selected
