क्या टिप्पणियां संग्रहित प्रक्रिया के प्रदर्शन में बाधा उत्पन्न कर सकती हैं?

समय-समय पर, एक वार्तालाप सामने आता है जहां लोगों को यह विश्वास हो जाता है कि टिप्पणियों का प्रदर्शन पर प्रभाव पड़ता है या नहीं।

सामान्य तौर पर, मैं कहूंगा कि, नहीं, टिप्पणियां प्रदर्शन को प्रभावित नहीं करती हैं , लेकिन "यह निर्भर करता है" अस्वीकरण के लिए हमेशा जगह होती है। आइए एक नमूना डेटाबेस और जंक से भरी तालिका बनाएं:

CREATE DATABASE CommentTesting;
GO
USE CommentTesting;
GO
SELECT TOP (1000) n = NEWID(), * INTO dbo.SampleTable 
  FROM sys.all_columns ORDER BY NEWID();
GO
CREATE UNIQUE CLUSTERED INDEX x ON dbo.SampleTable(n);
GO

अब, मैं चार संग्रहीत कार्यविधियाँ बनाना चाहता हूँ - एक टिप्पणियों के 20 वर्णों के साथ, एक 2000 के साथ, एक 20,000 के साथ, और एक 200,000 के साथ। और मैं इसे फिर से करना चाहता हूं जहां टिप्पणियां एम्बेडेड हैं * भीतर * प्रक्रिया के भीतर एक क्वेरी स्टेटमेंट, स्वतंत्र होने के विरोध में (जिसका एक्सएमएल योजना पर असर पड़ेगा)। अंत में, मैंने OPTION (RECOMPILE) . जोड़ने की प्रक्रिया को दोहराया क्वेरी के लिए।

DECLARE @comments nvarchar(max) = N'', 
        @basesql  nvarchar(max),
        @sql      nvarchar(max);
 
SELECT TOP (5000) -- * 40 character strings
  @comments += N'--' + RTRIM(NEWID()) + CHAR(13) + CHAR(10)
FROM sys.all_columns;
 
SET @basesql = N'CREATE PROCEDURE dbo.$name$
AS
BEGIN
  SET NOCOUNT ON;
 
  /* $comments1$ */
 
  DECLARE @x int;
  SELECT @x = COUNT(*) /* $comments2$ */ FROM dbo.SampleTable OPTION (RECOMPILE);
END';
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Small_Separate'),      N'$comments1$', LEFT(@comments, 20));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Medium_Separate'),     N'$comments1$', LEFT(@comments, 2000));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Large_Separate'),      N'$comments1$', LEFT(@comments, 20000));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'ExtraLarge_Separate'), N'$comments1$', LEFT(@comments, 200000));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Small_Embedded'),      N'$comments2$', LEFT(@comments, 20));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Medium_Embedded'),     N'$comments2$', LEFT(@comments, 2000));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'Large_Embedded'),      N'$comments2$', LEFT(@comments, 20000));
EXEC sys.sp_executesql @sql;
 
SET @sql = REPLACE(REPLACE(@basesql, N'$name$', N'ExtraLarge_Embedded'), N'$comments2$', LEFT(@comments, 200000));
EXEC sys.sp_executesql @sql;

अब, मुझे प्रत्येक प्रक्रिया को 100,000 बार चलाने के लिए कोड जनरेट करने की आवश्यकता है, अवधि को sys.dm_exec_procedure_stats से मापें , और कैश में योजना का आकार भी जांचें।

DECLARE @hammer nvarchar(max) = N'';
 
SELECT @hammer += N'
DBCC FREEPROCCACHE;
DBCC DROPCLEANBUFFERS;
GO
EXEC dbo.' + [name] + N';
GO 100000
 
SELECT [size of ' + [name] + ' (b)] = DATALENGTH(definition)
  FROM sys.sql_modules
  WHERE [object_id] = ' + CONVERT(varchar(32),([object_id])) + N';
 
SELECT [size of ' + [name] + ' (b)] = size_in_bytes
  FROM sys.dm_exec_cached_plans AS p
  CROSS APPLY sys.dm_exec_sql_text(p.plan_handle) AS t
  WHERE t.objectid = ' + CONVERT(varchar(32),([object_id])) + N';
 
SELECT N''' + [name] + N''', 
  avg_dur = total_elapsed_time*1.0/execution_count
  FROM sys.dm_exec_procedure_stats
  WHERE [object_id] = ' + CONVERT(varchar(32),([object_id])) + N';'
FROM sys.procedures
WHERE [name] LIKE N'%[_]Separate' OR [name] LIKE N'%[_]Embedded';
 
PRINT @hammer;

सबसे पहले, आइए प्रक्रिया निकायों के आकार को देखें। यहां कोई आश्चर्य की बात नहीं है, केवल यह पुष्टि करते हुए कि ऊपर मेरे निर्माण कोड ने प्रत्येक प्रक्रिया में टिप्पणियों के अपेक्षित आकार को उत्पन्न किया है:

अगला, कैश में योजनाएं कितनी बड़ी थीं?

आखिरकार, प्रदर्शन कैसा रहा? बिना OPTION (RECOMPILE) , यहां औसत निष्पादन समय है, मिलीसेकंड में - सभी प्रक्रियाओं में काफी सुसंगत:

औसत अवधि (मिलीसेकंड) - बिना विकल्प के (RECOMPILE) उन्हें>

DECLARE @hammer nvarchar(max) = N'';
 
SELECT @hammer += N'
DBCC FREEPROCCACHE;
DBCC DROPCLEANBUFFERS;
SELECT SYSDATETIME();
GO
EXEC dbo.' + [name] + N';
GO 100000
SELECT SYSDATETIME();';
 
PRINT @hammer;