मौजूदा डेटाबेस तालिका में एक पहचान कॉलम कैसे जोड़ें जिसमें बड़ी संख्या में पंक्तियां हों

अधिक समग्र लॉकिंग ओवरहेड के साथ समग्र प्रक्रिया शायद बहुत धीमी होगी लेकिन यदि आप केवल लेन-देन लॉग आकार की परवाह करते हैं तो आप निम्न को आजमा सकते हैं।

1. एक अशक्त पूर्णांक गैर-पहचान स्तंभ जोड़ें (मेटाडेटा केवल परिवर्तन)।
2. बैच में अद्वितीय अनुक्रमिक पूर्णांकों के साथ इसे अद्यतन करने के लिए कोड लिखें। यह प्रत्येक व्यक्तिगत लेनदेन के आकार को कम करेगा और लॉग आकार को नीचे रखेगा (सरल पुनर्प्राप्ति मॉडल मानकर)। नीचे दिया गया मेरा कोड 100 के बैचों में करता है, उम्मीद है कि आपके पास एक मौजूदा पीके है जिसे आप बार-बार स्कैन करने के बजाय वहां से उठा सकते हैं जहां आपने छोड़ा था, जो अंत में तेजी से लंबा होगा।
3. ALTER TABLE ... ALTER COLUMN का उपयोग करें कॉलम को NOT NULL के रूप में चिह्नित करने के लिए . इसके लिए पूरी तालिका को लॉक करना होगा और परिवर्तन को मान्य करने के लिए स्कैन करना होगा, लेकिन इसके लिए अधिक लॉगिंग की आवश्यकता नहीं होगी।
4. ALTER TABLE ... SWITCH . का उपयोग करें कॉलम को पहचान कॉलम बनाने के लिए। यह केवल मेटाडेटा परिवर्तन है।

उदाहरण कोड नीचे

/*Set up test table with just one column*/

CREATE TABLE table_1 ( original_column INT )
INSERT  INTO table_1
        SELECT DISTINCT
                number
        FROM    master..spt_values



/*Step 1 */
ALTER TABLE table_1 ADD id INT NULL



/*Step 2 */
DECLARE @Counter INT = 0 ,
    @PrevCounter INT = -1

WHILE @PrevCounter <> @Counter 
    BEGIN
        SET @PrevCounter = @Counter;
        WITH    T AS ( SELECT TOP 100
                                * ,
                                ROW_NUMBER() OVER ( ORDER BY @@SPID )
                                + @Counter AS new_id
                       FROM     table_1
                       WHERE    id IS NULL
                     )
            UPDATE  T
            SET     id = new_id
        SET @Counter = @Counter + @@ROWCOUNT
    END


BEGIN TRY;
    BEGIN TRANSACTION ;
     /*Step 3 */
    ALTER TABLE table_1 ALTER COLUMN id INT NOT NULL

    /*Step 4 */
    DECLARE @TableScript NVARCHAR(MAX) = '
    CREATE TABLE dbo.Destination(
        original_column INT,
        id INT IDENTITY(' + CAST(@Counter + 1 AS VARCHAR) + ',1)
        )

        ALTER TABLE dbo.table_1 SWITCH TO dbo.Destination;
    '       

    EXEC(@TableScript)


    DROP TABLE table_1 ;

    EXECUTE sp_rename N'dbo.Destination', N'table_1', 'OBJECT' ;


    COMMIT TRANSACTION ;
END TRY
BEGIN CATCH
    IF XACT_STATE() <> 0 
        ROLLBACK TRANSACTION ;
    PRINT ERROR_MESSAGE() ;
END CATCH ;