अभिव्यक्ति के साथ स्ट्रिंग को दशमलव में बदलें

मैं एक सीएलआर के साथ जाऊंगा, ऐसा कुछ (इसका एसईटी आधारित संचालन में काम करने का फायदा है जबकि गतिशील एसक्यूएल विकल्प (यानी अब्दुल का जवाब) नहीं होगा):

संपादित करें: सीएलआर डीएलएल (विजुअल स्टूडियो 2008) के लिए स्रोत कोड यहां पोस्ट किया गया:http:/ /www.heavencore.co.uk/filehub/uploaded/EvalFunction.zip

यदि आप स्वयं असेंबली को संकलित करना पसंद करते हैं, तो यहां कोड है:

Imports System
Imports System.Data
Imports System.Data.SqlClient
Imports System.Data.SqlTypes
Imports Microsoft.SqlServer.Server
Imports System.Runtime.InteropServices    

Partial Public Class UserDefinedFunctions
    <Microsoft.SqlServer.Server.SqlFunction()> _
    Public Shared Function EVAL(ByVal InputExpression As SqlString) As SqlDecimal
        Return Evaluate(InputExpression)
    End Function

    Private Shared Function Evaluate(ByVal expression As SqlString) As SqlDecimal
        Dim expressionStr As String = expression.ToString()
        Dim loDataTable = New DataTable()
        Dim loDataColumn = New DataColumn("Eval", GetType(Double), expressionStr)
        loDataTable.Columns.Add(loDataColumn)
        loDataTable.Rows.Add(0)
        Return ParseDecimal(loDataTable.Rows(0)("Eval").ToString(), 0)
    End Function

    Public Shared Function ParseDecimal(ByVal InputStr As String, Optional ByVal ReturnIfFail As Decimal = 0) As Decimal
        Dim ParseOutput As Decimal = 0
        If Decimal.TryParse(InputStr, ParseOutput) = False Then
            Return ReturnIfFail
        Else
            Return ParseOutput
        End If
    End Function
End Class

एक बार स्थापित और बाध्य होने के बाद आप यह कर सकते हैं:

SELECT Faktor, dbo.Eval(Faktor) as Result FROM Artikel

संपादित करें:ठीक है, मैंने अभी इसका परीक्षण किया है और यह सेट-आधारित संचालन आदि में ठीक काम करता है, स्थापना इस प्रकार थी:

-- Enable the CLR to run user-defined functions
EXEC sp_configure 
    'clr enabled' ,
    '1'
GO
RECONFIGURE
GO

-- Set the appropriate database security permission
ALTER DATABASE [TargetDatabase] SET TRUSTWORTHY ON
GO

-- Import the assembly
CREATE ASSEMBLY EvalFunction
FROM 'C:\bin\EvalFunction.dll'  
WITH PERMISSION_SET = EXTERNAL_ACCESS;
GO

-- Create the Eval function for easy use
CREATE FUNCTION dbo.Eval
    (
      @Expression NVARCHAR(255)
    )
RETURNS DECIMAL(18, 2)
AS EXTERNAL NAME 
    EvalFunction.[EvalFunction.UserDefinedFunctions].EVAL 
GO