एक नेस्टेड टेबल के अंदर एक एसोसिएटिव ऐरे को पॉप्युलेट करें

आपके पिछले प्रश्न के उत्तर में, मैंने उल्लेख किया था कि %rowtype के साथ संग्रह को पॉप्युलेट करना कठिन होगा खेत। जहां तक ​​मेरी जानकारी है, जब तक आप किसी रिकॉर्ड प्रकार के बजाय SQL-स्तरीय ऑब्जेक्ट प्रकार घोषित नहीं करते, आप bulk collect का उपयोग नहीं कर सकते इसके लिए (हालांकि यह जांचने लायक है कि क्या यह शायद 12c में बदल गया है)।

मेरा मानना ​​है कि आप एक सरल कर्सर लूप का उपयोग करने में फंस गए हैं जो आपके प्रकार में दो फ़ील्ड बनाता है (यानी %rowtype उप-फ़ील्ड और rowid फ़ील्ड) अलग से, और फिर संग्रह को एक बार में एक पंक्ति बनाता है:

create or replace package body dat_pkg is

    procedure transform_dat (p_batch_name data_test.batch_name%type)
    is

        cursor cur_dat is
        select rowid, a.*
        from   data_test a
        where  batch_name = p_batch_name;

        l_dat_tst typ_dat_tst;
        l_rec data_test%rowtype;

    begin

        for rec_dat in cur_dat loop
            l_rec.data_id := rec_dat.data_id;
            l_rec.data_value := rec_dat.data_value;
            l_rec.batch_name := rec_dat.batch_name;
            -- or use a counter you increment for this...
            l_dat_tst(l_dat_tst.count + 1).data_rec := l_rec;
            l_dat_tst(l_dat_tst.count).data_rowid := rec_dat.rowid;
        end loop;

        -- Do the Transformation here. Example --            

        for i in 1..l_dat_tst.count loop
            if l_dat_tst(i).data_rec.data_value = 'hello' then
                l_dat_tst(i).data_rec.data_value := 'was hello';
            else            
                l_dat_tst(i).data_rec.data_value := 'was not hello';
            end if;
        end loop;

        -- update the table            
        proc_test (p_dat => l_dat_tst);

    end transform_dat;

    procedure proc_test (p_dat  typ_dat_tst)
    is
    begin

        for i in 1..p_dat.count loop

            update  data_test        
            set     data_value  = p_dat(i).data_rec.data_value  
            where   data_id     = p_dat(i).data_rec.data_id
            and     rowid       = p_dat(i).data_rowid;

        end loop;

    end proc_test;

end dat_pkg;
/    

जैसा कि पहले भी चर्चा की गई है, उप-फ़ील्ड-रिकॉर्ड के फ़ील्ड के संदर्भ ठीक से योग्य होने चाहिए, इसलिए मैंने .data_rec डाला है दोनों प्रक्रियाओं में संदर्भ में। मैंने आईडी के बजाय मूल्य को संशोधित करने के लिए डमी परिवर्तन को बदल दिया है, क्योंकि इसका मतलब है कि कोई अपडेट कभी नहीं होने वाला था।

कुछ डमी डेटा के साथ डेमो:

insert into data_test values (1, 'hello', 'test');
insert into data_test values (2, 'hello', 'test');
insert into data_test values (3, 'hello', 'exclude');
insert into data_test values (4, 'goodbye', 'test');


exec dat_pkg.transform_dat('test');

select * from data_test;

   DATA_ID DATA_VALUE           BATCH_NAME          
---------- -------------------- --------------------
         1 was hello            test                
         2 was hello            test                
         3 hello                exclude             
         4 was not hello        test