Oracle से PostgreSQL में फ़ंक्शन कनवर्ट करना

फ़ंक्शन strpos(str, sub) Postgres में instr(str, sub) . के बराबर है ओरेकल में। दुर्भाग्य से, फ़ंक्शन में तीसरे और चौथे पैरामीटर नहीं हैं, इसलिए पोस्टग्रेज़ में अभिव्यक्ति अधिक जटिल होनी चाहिए।

फ़ंक्शन substr(str, n) str . का एक विकल्प देता है n . से शुरू स्थिति।

instr(str, ch, instr(str, sub), 1);                               --oracle
strpos(substr(str, strpos(str, sub)), ch) + strpos(str, sub) - 1; --postgres

instr() . के रूप में एक शक्तिशाली कार्य है जिसे मैंने इसे अपनी आवश्यकताओं के लिए plpgsql में लिखा है।

create or replace function instr(str text, sub text, startpos int = 1, occurrence int = 1)
returns int language plpgsql immutable
as $$
declare 
    tail text;
    shift int;
    pos int;
    i int;
begin
    shift:= 0;
    if startpos = 0 or occurrence <= 0 then
        return 0;
    end if;
    if startpos < 0 then
        str:= reverse(str);
        sub:= reverse(sub);
        pos:= -startpos;
    else
        pos:= startpos;
    end if;
    for i in 1..occurrence loop
        shift:= shift+ pos;
        tail:= substr(str, shift);
        pos:= strpos(tail, sub);
        if pos = 0 then
            return 0;
        end if;
    end loop;
    if startpos > 0 then
        return pos+ shift- 1;
    else
        return length(str)- length(sub)- pos- shift+ 3;
    end if;
end $$;

कुछ जांच (उदाहरण OLAP DML Functions ):

select instr('Corporate Floor', 'or', 3, 2);  -- gives 14
select instr('Corporate Floor', 'or', -3, 2); -- gives 2

कोई reverse() नहीं है पोस्टग्रेज 8.2 में कार्य करें। आप इसका उपयोग कर सकते हैं:

-- only for Postgres 8.4 or earlier!
create or replace function reverse(str text)
returns text language plpgsql immutable
as $$
declare
    i int;
    res text = '';
begin
    for i in 1..length(str) loop
        res:= substr(str, i, 1) || res;
    end loop;
    return res;
end $$;