पीएल/एसक्यूएल फ़ंक्शन से डेटा कैसे प्राप्त करें यदि पैरामीटर में एकल पैरामीटर के साथ फ़ंक्शन में एक से अधिक मान हैं

कुछ सीमित जानकारी के साथ मैं नीचे आया हूं। मुझे अभी भी कोई सुराग नहीं है कि आपके स्टेटिक कर्सर के साथ क्या हो रहा है जिसका आपने अपने प्रश्न में उल्लेख किया है जो आपके f_process_data() में परिभाषित है। समारोह। चूंकि मुझे इस फ़ंक्शन में पूरा कोड नहीं पता है, इसलिए मैंने बस अपना खुद का लिखा और CURSOR को SYS_REFCURSOR के रूप में घोषित कर दिया क्योंकि फ़ंक्शन वही देता है।

कृपया मुझे बताएं कि क्या यह काम करता है या अगर मुझे कुछ महत्वपूर्ण जानकारी याद आ रही है। मुझे लगता है कि आपको उपयोगी समाधान प्रदान करने के लिए मेरे पास महत्वपूर्ण जानकारी की कमी है।

उत्पाद नामक मॉक-अप तालिका में निम्नलिखित कॉलम और डेटा शामिल हैं। छवि देखें।

DECLARE

  /* Store Ref Cursor returned by f_process_data() Function */
  v_result_cursor   SYS_REFCURSOR;

  /* Declare Record so we can store the data FETCHed from the Cursor */
  rec_products      products%ROWTYPE;

  /* Declare a couple Product Variables for Proof of Concept */
  v_sausage         NUMBER;
  v_ham             NUMBER;

  /* Store output */
  n_id              NUMBER;
  v_id_product      VARCHAR2(100);

  /* Declare Type of TABLE NUMBER */
  TYPE  nt_type IS TABLE OF NUMBER;

  /* Create Array/Table/Collection of type nt_type to store product ids */
  nt_product_ids    nt_type;

  /* Returns a Ref Cursor based on the product_id used as Input to this function */
  FUNCTION f_process_data(p_id_process IN NUMBER, p_id_product IN NUMBER)
  RETURN SYS_REFCURSOR
  AS
    /* Declare Ref Cursor that will be Returned */
    rc_result_cursor   SYS_REFCURSOR;    

  BEGIN 
    /* Open Ref Cursor based on Product ID parameter */
    OPEN rc_result_cursor FOR SELECT * FROM products WHERE item_id = p_id_product;

    RETURN rc_result_cursor;

  END f_process_data
  ;

BEGIN

  /* Set Product Variables to IDs */
  v_sausage       := 2002;
  v_ham           := 2009;

  /* Store product ids into a Number Table so we can Loop thru it */
  nt_product_ids  :=  nt_type (v_sausage,v_ham);

  FOR r IN nt_product_ids.FIRST .. nt_product_ids.LAST
  LOOP
    /* Get Ref Cursor using SINGLE Product ID */
    v_result_cursor := f_process_data(1, nt_product_ids(r));

    LOOP

    FETCH v_result_cursor INTO rec_products;

    n_id            :=  rec_products.item_id;
    v_id_product    :=  rec_products.item;

    EXIT WHEN v_result_cursor%NOTFOUND;

    dbms_output.put_line('Product_id: ' || n_id);
    dbms_output.put_line('Product: ' || v_id_product);  

    END LOOP; /* Cursor Loop */

    /* Close Cursor */
    CLOSE v_result_cursor;

  END LOOP; /* Product IDs Loop */

EXCEPTION WHEN OTHERS
  THEN CLOSE v_result_cursor;

END;